MacFormat 1994 November/macformat-018.iso/Comms Spectacular/AppleTalk Remote Access/NetComm ARA Scripts V1.1/NetComm SM M9F

Text File | 1994-04-07 | 4.3 KB | 254 lines | [mlts/slnk]

!"NetComm SmartModem M9F - VFC 7th April 1994 - NJS - v1.1
!
! Please note that you will need a macintosh Hardware Handshake cable to
! use any modem with AppleTalk Remote Access at anything over 9600bps.
!
@ORIGINATE
@ANSWER
!
@LABEL 1
serreset 38400, 0, 8, 1
!
! first sync up the modem
!
matchclr
matchstr 1 3 "A"
settries 0
@LABEL 2
write "A"
matchread 10
inctries
iftries 4 3
jump 2
@LABEL 3
matchclr
settries 0
matchstr 1 4 "OK\13\10"
write "T\13"
matchread 30
!
!    Now, recall the modems factory configuration
!
@LABEL 4
matchstr 1 5 "OK\13\10"
write "AT&F\13"
matchread 30
inctries
iftries 2 59
! Modem is not responding, reset
DTRClear
pause 5
DTRSet
jump 4
!
! Next, Set up the configuration:
! Echo off, turn off auto answer
! Ignore DTR (needed when using a a hardware handshake cable)
!
@LABEL 5
matchstr 1 6 "OK\13\10"
write "ATE0&D0S0=0\13"
matchread 30
jump 59
!
! Connect in Constant speed mode, no mnp, Hardware flow control
!
@LABEL 6
matchstr 1 7 "OK\13\10"
write "AT\\N0&D0&K3%C0X3\13"
matchread 30
jump 59
!
! Set up the speaker: If speaker flag is "1", jump to 8;  else turn off speaker
!
@LABEL 7
ifstr 2 8 "1"
matchstr 1 8 "OK\13\10"
write "ATM0\13"
matchread 30
jump 59
!
! The modem is ready.  So enable answering, or originate a call
!
@LABEL 8
ifANSWER 30
! Dial with 19200 VFC enabled
note "Dialing ^1" 3
write "ATS0=0B18DT^1\13"
!
@LABEL 9
matchstr 1 11 "CONNECT 1200\13\10"
matchstr 2 12 "CONNECT 2400\13\10"
matchstr 3 13 "CONNECT 4800\13\10"
matchstr 4 14 "CONNECT 7200\13\10"
matchstr 5 15 "CONNECT 9600\13\10"
matchstr 6 16 "CONNECT 12000\13\10"
matchstr 7 17 "CONNECT 14400\13\10"
matchstr 8 18 "CONNECT 16800\13\10"
matchstr 9 19 "CONNECT 19200\13\10"
matchstr 10 50 "NO CARRIER\13\10"
matchstr 11 50 "ERROR\13\10"
matchstr 12 52 "NO DIALTONE\13\10"
matchstr 13 53 "BUSY\13\10"
matchstr 14 54 "NO ANSWER\13\10"
matchread 700
jump 59
!
@LABEL 11
note "Modem connection established at 1200 bps." 2
CommunicatingAt 1200
jump 25
!
@LABEL 12
note "Modem connection established at 2400 bps." 2
CommunicatingAt 2400
jump 25
!
@LABEL 13
note "Modem connection established at 4800 bps." 2
CommunicatingAt 4800
jump 25
!
@LABEL 14
note "Modem connection established at 7200 bps." 2
CommunicatingAt 7200
jump 25
!
@LABEL 15
note "Modem connection established at 9600 bps." 2
CommunicatingAt 9600
jump 25
!
@LABEL 16
note "Modem connection established at 12000 bps." 2
CommunicatingAt 12000
jump 25
!
@LABEL 17
note "Modem connection established at 14400 bps." 2
CommunicatingAt 14400
jump 25
!
@LABEL 18
note "Modem connection established at 16800 bps." 2
CommunicatingAt 16800
jump 25
!
@LABEL 19
note "Modem connection established at 19200 bps." 2
CommunicatingAt 19200
jump 25
!
@LABEL 25
HSReset 0 1 0 0 0 1
ifANSWER 21
pause 30
@LABEL 21
exit 0
!
!
! Set up the modem to answer
@LABEL 30
write "ATS0=2B0\13"
matchstr 1 31 "OK\13\10"
matchread 30
jump 59
!
@LABEL 31
matchstr 1  32 "RING\13\10"
matchstr 2  11 "CONNECT 1200\13\10"
matchstr 3  12 "CONNECT 2400\13\10"
matchstr 4  13 "CONNECT 4800\13\10"
matchstr 5  14 "CONNECT 7200\13\10"
matchstr 6  15 "CONNECT 9600\13\10"
matchstr 7  16 "CONNECT 12000\13\10"
matchstr 8  17 "CONNECT 14400\13\10"
matchstr 9  18 "CONNECT 16800\13\10"
matchstr 10  19 "CONNECT 19200\13\10"
matchstr 11  50 "NO CARRIER\13\10"
matchstr 12  50 "ERROR\13\10"
matchstr 13  52 "NO DIALTONE\13\10"
matchstr 14  53 "BUSY\13\10"
matchstr 15 54 "NO ANSWER\13\10"
matchread 700
jump 31
!
@LABEL 32
userhook 1
note "Answering phone…" 2
jump 31
!
! 50: error messages
!
@LABEL 50
exit -6021
!
@LABEL 52
exit -6020
!
@LABEL 53
exit -6022
!
@LABEL 54
exit -6023
!
@LABEL 59
exit -6019
!
! Hang up the modem
!
@HANGUP
@LABEL 60
settries 0
@LABEL 61
matchclr
matchstr 1 63 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 63 "ERROR\13\10"
write "ATH\13"
matchread 30
inctries
iftries 3 63
! no response, try escape sequence
matchclr
matchstr 1 62 "OK\13\10"
write "+++"
matchread 20
!
! No response from modem, toggle DTR
!
DTRClear
pause 5
DTRSet
jump 61
!
@LABEL 62
pause 5
write "ATH0\13"
matchstr 1 63 "OK\13\10"
matchstr 2 63 "NO CARRIER\13\10"
matchstr 3 63 "ERROR\13\10"
matchread 70
jump 61
!
! Recall factory settings
!
@LABEL 63
pause 5
matchclr
matchstr 1 64 "OK\13\10"
write "AT&F\13"
matchread 30
!
! Turn off auto answer
!
@LABEL 64
write "ATS0=0\13"
matchstr 1 65 "OK\13\10"
matchread 30
!
!
@LABEL 65
exit 0